globals
[
  max-grain    ; maximální množství zrní, které může na políčkách vyrůst
]

patches-own
[
  grain-here      ; aktuální množství zrní na tomto políčku
  max-grain-here  ; maximální množství zrní pro dané políčko
]

turtles-own
[
  age              ; stáří želvy
  wealth           ; množství zrní, které želva vlastní
  life-expectancy  ; maximální věk, kterého se může želva dožít
  metabolism       ; kolik zrní sní želva v každém kole
  vision           ; kolik políček před sebe želva dohlédne
]

;;;
;;; Procedury tlačítka Připrav
;;;

to setup
  ca
  ;; nastaví globální proměnné na příslušné hodnoty
  set max-grain 50
  ;; spouští ostatní procedury k přípravě různých částí modelu
  setup-patches
  setup-turtles
  setup-plots
  ;; vynese do grafu výchozí situaci v modelu
  update-plots
end

;; nastaví výchozí množství zrní pro všechna políčka
to setup-patches
  ;; některým políčkům je přiřazen nejvyšší možný počet zrní 
  ;; tato políčka reprezentují nejvýnosnější pole
  ask patches
    [ set max-grain-here 0
      if (random-float 100.0) <= procento-nejlepsi-pudy
        [ set max-grain-here max-grain
          set grain-here max-grain-here ] ]
  ;; rozprostře zrní po celém světě a přidá více 
  ;; ve prospěch nejvýnosnějším polím
  repeat 5
    [ ask patches with [max-grain-here != 0]
        [ set grain-here max-grain-here ]
      diffuse grain-here 0.25 ]
  repeat 10
    [ diffuse grain-here 0.25 ]          ;; rozptýlí zrní po okolí o něco více
  ask patches
    [ set grain-here floor grain-here    ;; zaokrouhlí množství zrní na celá čísla
      set max-grain-here grain-here      ;; výchozí množství zrní je zároveň maximem
      recolor-patch ]
end

to recolor-patch  ;; procedura políček -- využívá škálu barev k vyjádření množství zrní na políčkách (hodnoty políček)
  set pcolor scale-color yellow grain-here 0 max-grain
end

;; připraví výchozí hodnoty pro proměnné želv
to setup-turtles
  set-default-shape turtles "person"
  crt pocet-lidi
    [ move-to one-of patches  ;; umístí želvy do středů políčk
      set size 1.5  ;; pro snažší viditelnost
      set-initial-turtle-vars
      set age random life-expectancy ]
  recolor-turtles
end

to set-initial-turtle-vars
  set age 0
  face one-of neighbors4
  set life-expectancy delka-zivota-min +
                        random (delka-zivota-max - delka-zivota-min + 1)
  set metabolism 1 + random metabolismus-max
  set wealth metabolism + random 50
  set vision 1 + random max-videni
end

;; Nastaví želvám třídu podle bohatství -- pokud má želva méně než třetinu
;; majetku nejbohatší želvy, pak je červená. Pokud vlastní mezi jednou a 
;; dvěma třetinami tohoto majetku, pak je zelená. Nejbohatší želvy jsou modré.
to recolor-turtles
  let max-wealth max [wealth] of turtles
  ask turtles
    [ ifelse (wealth <= max-wealth / 3)
        [ set color red ]
        [ ifelse (wealth <= (max-wealth * 2 / 3))
            [ set color green ]
            [ set color blue ] ] ]
end

;;;
;;; Procedury tlačítka Start
;;;

to go
  ask turtles
    [ turn-towards-grain ]  ;; želva se otočí směrem, kde je v rámci jejího dohledu nejvíce zrní
  harvest
  ask turtles
    [ move-eat-age-die ]
  recolor-turtles

  ;; umožňuje růst zrní v průběhu času
  if ticks mod interval-rustu-zrni = 0
    [ ask patches [ grow-grain ] ]

  tick
  update-plots
end

;; procedura určující směr, který je nejvýnosnější pro každou želvu z hlediska
;; množství zrní na okolních políčkách (v závislosti na tom, jak daleko želva vidí)
to turn-towards-grain  ;; procedura želv
  set heading 0
  let best-direction 0
  let best-amount grain-ahead
  set heading 90
  if (grain-ahead > best-amount)
    [ set best-direction 90
      set best-amount grain-ahead ]
  set heading 180
  if (grain-ahead > best-amount)
    [ set best-direction 180
      set best-amount grain-ahead ]
  set heading 270
  if (grain-ahead > best-amount)
    [ set best-direction 270
      set best-amount grain-ahead ]
  set heading best-direction
end

to-report grain-ahead  ;; procedura želv
  let total 0
  let how-far 1
  repeat vision
    [ set total total + [grain-here] of patch-ahead how-far
      set how-far how-far + 1 ]
  report total
end

to grow-grain  ;; procedura políček
  ;; pokud na políčku není maximální možné množství zrní, pak procedura 
  ;; přidá množství zrní, odpovídající hodnotě parametru kolik-zrni-dorusta
  if (grain-here < max-grain-here)
    [ set grain-here grain-here + kolik-zrni-dorusta
      ;; pokud nové množství zrní na políčku překročilo maximální
      ;; kapacitu, srovnej toto množství na maximum
      if (grain-here > max-grain-here)
        [ set grain-here max-grain-here ]
      recolor-patch ]
end

;; každá želva sklízí zrní na svém políčku. Poud je jich na jednom
;; políčku více, rozděluje se mezi ně zrní rovnoměrně
to harvest
  ; želvy rovnoměrně sklízí zrní, dokud není vyčerpáno
  ask turtles
    [ set wealth floor (wealth + (grain-here / (count turtles-here))) ]
  ;; želvy postupně sklidí všechno zrní z daného políčka, které podle toho změní barvu
  ask turtles
    [ set grain-here 0
      recolor-patch ]
end

to move-eat-age-die  ;; procedura želv
  fd 1
  ;; spotřebuj zrní úměrně svému metabolismu
  set wealth (wealth - metabolism)
  ;; zestárni o časovou jednotku
  set age (age + 1)
  ;; zkontroluj podmínky smrti: pokud nemáš žádné zrní
  ;; nebo jsi starší než je očekávaná doba života, pak
  ;; zemřeš a jsi znovu narozen s novými náhodnými 
  ;; hodnotami proměnných
  if (wealth < 0) or (age >= life-expectancy)
    [ set-initial-turtle-vars ]
end

;;;
;;; Procedury grafu
;;;

to setup-plots
  set-current-plot "Vývoj tříd"
  set-plot-y-range 0 pocet-lidi
  set-current-plot "Histogram tříd"
  set-plot-y-range 0 pocet-lidi
end

to update-plots
  update-class-plot
  update-class-histogram
  update-lorenz-and-gini-plots
end

;; vytvoří čárový graf, ukazující počet lidí v jednotlivých třídách (podle bohatství)
to update-class-plot
  set-current-plot "Vývoj tříd"
  set-current-plot-pen "chudí"
  plot count turtles with [color = red]
  set-current-plot-pen "střední"
  plot count turtles with [color = green]
  set-current-plot-pen "bohatí"
  plot count turtles with [color = blue]
end

;; ;; vytvoří histogram, ukazující počet lidí v jednotlivých třídách (podle bohatství)
to update-class-histogram
  set-current-plot "Histogram tříd"
  plot-pen-reset
  set-plot-pen-color red
  plot count turtles with [color = red]
  set-plot-pen-color green
  plot count turtles with [color = green]
  set-plot-pen-color blue
  plot count turtles with [color = blue]
end

to update-lorenz-and-gini-plots
  set-current-plot "Lorenzova křivka"
  clear-plot

  ;; nakreslí diagonálu z levého dolního rohu do pravého horního
  set-current-plot-pen "diag"
  plot 0
  plot 100

  set-current-plot-pen "Lorenz"
  set-plot-pen-interval 100 / pocet-lidi
  plot 0

  let sorted-wealths sort [wealth] of turtles
  let total-wealth sum sorted-wealths
  let wealth-sum-so-far 0
  let index 0
  let gini-index-reserve 0

  ;; dále bude sestrojena Lorenzova křivka a zároveň
  ;; je vypočítán Giniho index
  repeat pocet-lidi [
    set wealth-sum-so-far (wealth-sum-so-far + item index sorted-wealths)
    plot (wealth-sum-so-far / total-wealth) * 100
    set index (index + 1)
    set gini-index-reserve
      gini-index-reserve +
      (index / pocet-lidi) -
      (wealth-sum-so-far / total-wealth)
  ]

  ;; vykreslí Giniho index v grafu
  set-current-plot "Giniho index"
  plot (gini-index-reserve / pocet-lidi) / area-of-equality-triangle
end

to-report area-of-equality-triangle
  ;; tento výpočet není nutný, pokud má proměnná pocet-lidi vysokou 
  ;; hodnotu -- pro tuto vysokou hodnotu můžeme použít přibližný odhad 0.5
  report (pocet-lidi * (pocet-lidi - 1) / 2) / (pocet-lidi ^ 2)
end


; *** NetLogo 4.0.2 Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING
; IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
; Converted from StarLogoT to NetLogo, 2001.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Wealth Distribution model.
; http://ccl.northwestern.edu/netlogo/models/WealthDistribution.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/WealthDistribution
; for terms of use.
;
; *** End of NetLogo 4.0.2 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
184
10
602
449
25
25
8.0
1
10
1
1
1
0
1
1
1
-25
25
-25
25
1
1
1
ticks

CC-WINDOW
5
648
917
743
Command Center
0

BUTTON
8
256
79
289
Připrav
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
108
256
175
289
Start
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
8
72
176
105
max-videni
max-videni
1
15
5
1
1
NIL
HORIZONTAL

SLIDER
8
301
176
334
interval-rustu-zrni
interval-rustu-zrni
1
10
1
1
1
NIL
HORIZONTAL

SLIDER
8
106
176
139
metabolismus-max
metabolismus-max
1
25
15
1
1
NIL
HORIZONTAL

SLIDER
8
38
176
71
pocet-lidi
pocet-lidi
2
1000
250
1
1
NIL
HORIZONTAL

SLIDER
8
208
176
241
procento-nejlepsi-pudy
procento-nejlepsi-pudy
5
25
10
1
1
%
HORIZONTAL

SLIDER
8
174
176
207
delka-zivota-max
delka-zivota-max
1
100
83
1
1
NIL
HORIZONTAL

PLOT
3
454
255
634
Vývoj tříd
Čas
Počet lidí
0.0
50.0
0.0
250.0
true
true
PENS
"chudí" 1.0 0 -2674135 true
"střední" 1.0 0 -10899396 true
"bohatí" 1.0 0 -13345367 true

SLIDER
8
335
176
368
kolik-zrni-dorusta
kolik-zrni-dorusta
1
10
4
1
1
NIL
HORIZONTAL

SLIDER
8
140
176
173
delka-zivota-min
delka-zivota-min
1
100
1
1
1
NIL
HORIZONTAL

PLOT
257
454
469
634
Histogram tříd
Třídy
Počet lidí
0.0
3.0
0.0
250.0
false
false
PENS
"default" 1.0 1 -2674135 true

PLOT
471
454
687
634
Lorenzova křivka
Populace %
Bohatství %
0.0
100.0
0.0
100.0
false
true
PENS
"Lorenz" 1.0 0 -2674135 true
"diag" 100.0 0 -16777216 true

PLOT
689
454
908
634
Giniho index
Čas
Giniho index
0.0
50.0
0.0
1.0
true
false
PENS
"default" 1.0 0 -13345367 true

@#$#@#$#@
CO JE TO?
---------
Tento model simuluje rozdělení bohatství ve společnosti. Známé rčení "Bohatí bohatnou a chudí chudnou." ilustruje nerovnoměrnost rozdělení bohatství. Model produkuje rozdělení bohatství, které odpovídá tzv. Paretovu zákonu. Tento zákon popisuje empiricky ověřitelnou skutečnost, že v průměru okolo 20 % lidí vlastní 80 % všeho bohatství. Agenti v modelu jsou rozděleni do tří tříd podle bohatství. Existuje zde velké množství červených "chudých agentů", méně je zelených "střední třída" a ještě mnohem méně modrých "bohatých" agentů. Každý člověk z chudé třídy vlastní 0 až 1/3 maximálního bohatství (maximální bohatství je bohatství nejbohatšího člověka v daném kole), člověk ze střední třídy vlastní 1/3 až 2/3 maximálního bohatství a bohatý člověk vlastní 2/3 až maximum z maximálního bohatství. 

JAK TO FUNGUJE?
---------------
Tento model je adaptací původního modelu Epsteina a Axtella "Sugarscape". Místo metafory cukru, který používal původní model, používáme zde metaforu zrní. Na každém políčku roste jisté množství zrní a je stanoveno, kolik zrní na kterém políčku může maximálně vyrůst. Lidé sbírají zrní z políček a jedí ho, aby přežili. Množství nastřádaného zrní představuje bohatství. 

Na začátku mají lidé zhruba stejné bohatství. Lidé mohou chodit po krajině a sbírat tolik zrní kolik chtějí. Každý člověk se pohne tím směrem, kde leží nejvíce zrní. Lidé se ale liší v tom, jak daleko (kolik políček) vidí, tedy i ve svých schopnostech zjistit celkové množství zrní ve větší vzdálenosti. V každém kole musí sníst každý člověk jistou část svého zrní. Toto množství představuje náročnost jejich metabolismu a může se u různých lidí lišit. Lidé také mají omezenou dobu života. Když se člověku doba jeho života naplní nebo mu dojde zrní, tak zemře. Místo něj se objeví nový agent s náhodným metabolismem a množstvím zrní. Neexistuje zde dědičnost, nový agent nedědí po svém předchůdci jeho bohatství. 

Pro pozorování míry nerovnoměrnosti v rozdělení bohatství používáme graf, který se nazývá Lorenzova křivka. Na ose x setřídíme populaci zleva doprava podle bohatství, a poté vyneseme postupně načítané celkové bohatství (od nejchudších k nejbohatším) na osu y. Tak můžeme vidět kolik procent bohatství vlastní jisté procento populace. Rozsah hodnot na obou osách je tedy 0 % až 100 %.

Jiný způsob, jak porozumět Lorenzově křivce, je představit si, že ve společnosti 100 lidí je k dispozici 100 dolarů. Každý člověk představuje 1 % populace a každý dolar 1 % bohatství. Seřadíme lidi podle jejich bohatství od nejchudších k nejbohatším na ose x. Na osu vyneseme vždy součet bohatství příslušného člověka a bohatství všech lidí chudších než on. Například nějaký člověk X, který je dvacátý nejchudší ze sta, stojí na ose x na dvacátém místě zleva a na ose y mu přísluší hodnota rovná počtu dolarů, které vlastní tento člověk a všichni lidé chudší než on dohromady. Tato hodnota představuje procento bohatství, které vlastní nejchudších 20 % populace.
Kdyby Lorenzova křivka byla přímá diagonální linie se sklonem 45 stupňů (měla by směrnici 1), tak by bylo bohatství populace rozděleno zcela rovnoměrně, každý by vlastnil jeden dolar. Naopak pokud by pouze jeden člověk vlastnil všechno bohatství, Lorenzova křivka by vypadala jako obrácené "L". Tedy 99 % lidí nevlastní ani jeden dolar a poslední nejbohatší stý člověk má všech 100 dolarů. V praxi se Lorenzova křivka nachází někde mezi diagonálou a obráceným "L" .   

Z Lorenzovy křivky můžeme odvodit tzv. Giniho index (nebo Giniho koeficient), který je číselnou mírou nerovnoměrnosti rozdělení bohatství. Giniho index je podíl plochy mezi Lorenzovou křivkou a diagonálou a celkové plochy pod diagonálou (což je vždy 0.5 - plocha pravoúhlého trojúhelníku s odvěsnami délky 1). Kdyby Lorenzova křivka byla diagonální linie pod úhlem 45 stupňů, byl by Giniho index 0. Kdyby Lorenzova křivka vypadala jako obrácené "L", byl by Giniho index 1. Tedy Giniho index je přímo úměrný  nerovnoměrnosti rozdělení bohatství a pohybuje se v rozmezí 0 až 1.

JAK MODEL OVLÁDAT?
------------------
PŘIPRAV náhodně určí kolik zrní bude kde růst a rozmístí lidi s náhodně nastaveným bohatstvím a metabolismem. START zahajuje a ukončuje simulaci. 

Nastavení PROCENTO-NEJLEPSI-PUDY určuje počáteční hustotu políček, na kterých poroste maximální množství zrní. INTERVAL-RUSTU-ZRNI nastavuje, jak často bude zrní dorůstat, KOLIK-ZRNI-DORUSTA nastavuje kolik zrní v tomto intervalu doroste.

POCET-LIDI nastavuje počáteční počet lidí. DOBA-ZIVOTA-MIN je minimální počet kol, po kterých může člověk umřít stářím (ale může umřít i dříve pokud mu dojde zrní). DOBA-ZIVOTA-MAX je maximální počet kol, po kterých člověk umírá stářím. METABOLISMUS-MAX nastavuje maximální objem zrní, který musí člověk v každém kole sníst, aby přežil . VIDENI-MAX nastavuje maximální vzdálenost (počet políček), do které může člověk vidět. 

Graf VÝVOJ TŘÍD ukazuje vývoj počtu lidí v jednotlivých třídách v čase. HISTOGRAM TŘÍD ukazuje rozdělení do tříd v aktuálním kole. LORENZOVA KŘIVKA ukazuje Lorenzovu křivku v aktuálním kole a také diagonální linii se sklonem 45 stupňů. GINIHO INDEX ukazuje vývoj Giniho indexu v čase. Lorenzova křivka a Giniho index jsou aktualizovány pouze každých pět kol (kvůli výpočetní náročnosti). 

VŠIMNĚTE SI
-----------
Všimněte si rozdělení bohatství ve třídách. Jsou třídy stejně početné? 

Model ukazuje platnost Paretova zákona, který tvrdí, že menší část populace vlastní větší část bohatství. Proč k tomu dochází? 

Mohou lidé v modelu změnit svoji třídu (zbohatnout, zchudnout)?

Za jak dlouho dosáhnou počty příslušníků jednotlivých tříd stabilních hodnot?

Mění se nějak rozdělení bohatství v delším čase? (Rada: sledujte vývoj Giniho indexu. Stabilizuje se na určité hodnotě nebo osciluje?)

Zkuste najít na internetu informace o Giniho indexu jednotlivých zemí, např. České republiky. Odpovídá či neodpovídá modelový Giniho index skutečným indexům? Proč?
(Viz např. http://en.wikipedia.org/wiki/Gini_index#Income_Gini_indices_in_the_world)


ZKUSTE SI
---------
Jak se mění Giniho index pro jednotlivá nastavení? 

Zůstává pro některá nastavení zachována víceméně stejná hodnota Giniho indexu pro širokou škálu různých hodnot (chování modelu je tzv. robustní)?

Existují nastavení, pro která se model nechová podle Paretova zákona?

ROZŠÍŘENÍ MODELU
----------------
Zkuste na začátku umístit všechny lidi na jedno políčko. Co se stane?

Zkuste nastavit všem lidem při narození stejné bohatství nebo maximální vidění. Dojde i tak po nějaké době k nerovnoměrnému rozložení bohatství? Bude se nějak lišit Giniho index pro náhodné a pro stejné nastavení těchto parametrů?

Nechte každého nového člověka zdědit část bohatství umírajícího člověka. 

Umožněte, aby nashromážděné zrní dávalo svému vlastníkovi nějakou výhodu či nevýhodu (např. zlepšení vidění nebo naopak zpomalení).

Bude se model chovat stejně, pokud by byla úrodnost půdy přiřazena políčkům zcela náhodně a ne v gradientech? Zkuste přidat různé typy krajin a každé přiřaďte zvláštní tlačítko PŘIPRAV. 

Umožněte navrhněte? nějaký způsob dědičnosti metabolismu či vidění. Dojde k evoluci, ve které budou přežívat ti nejlépe "přizpůsobení"?
Zkuste do modelu přidat sezónní změny. Např. v jistých částech krajiny může růst zrní lépe v jistých časových úsecích. 

Dokážete změnit model tak, aby lidé dosahovali rovnoměrného rozdělení bohatství?

Způsob, jakým je napsán kód programu modelu (procedures), zapřičiňuje, že lidé se budou občas následovat. To je obzvláště zřetelné, když nastavíte počet lidí relativně nízký, např. mezi 50 a 100, a nastavíte vysokou maximální délku života. Proč dochází k tomuto jevu? (Rada: Kdy a jak probíhá rozhodování, kam se má člověk vydat?)
Zkuste změnit kód programu tak, aby k tomuto jevu nedocházelo. Změní se chování modelu?

PROGRAMOVACÍ ZAJÍMAVOSTI NETLOGA
--------------------------------
K obarvení políček je použit reporter "scale-color". Barva políček je škálována podle jeho hodnoty.

Všimněte si použití seznamů (lists) při vykreslování Lorenzovy křivky a výpočtu Giniho indexu. 

PODĚKOVÁNÍ A ODKAZY
-------------------
Pro vysvětlení Paretova zákona viz http://www.xrefer.com/entry/445978.

Tento model je založen na modelu popsaném v  Epstein, J. & Axtell R. (1996). Growing Artificial Societies: Social Science from the Bottom Up. Washington, DC: Brookings Institution Press.
 
Při citování tohoto modelu ve vědeckých publikacích použijte prosím následující odkaz:   Wilensky, U. (1998).  NetLogo Wealth Distribution model.  http://ccl.northwestern.edu/netlogo/models/WealthDistribution.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V jiných publikacích, uveďte prosím tyto informace:  Copyright 1998 Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/WealthDistribution for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.3
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

@#$#@#$#@