patches-own
[
  new-color       ;; aktuálně nová barva - vždy černá nebo bílá
  inner-neighbors ;; ostatní buňky ve vnitřním kruhu kolem centrální buňky
  outer-neighbors ;; ostatní buňky v prstenci kolem centrální buňky (většinou bez buněk, které by se přímo dotýkaly)
]

to setup
  clear-all
  ;; vypočítá vnitřní a vnější sousedy v elipse kolem buňky
  ask patches
  [
    set inner-neighbors ellipse-in vnitrni-radius-x vnitrni-radius-y
    ;; vnější sousedé potřebují více výpočtů neboť chceme získat pouze samotný prstenec, nikoliv celý kruh
    set outer-neighbors ellipse-ring vnejsi-radius-x vnejsi-radius-y vnitrni-radius-x vnitrni-radius-y
  ]

  ifelse any? patches with [ count outer-neighbors = 0 ]
    [ user-message word " Nastavení, ve kterém je VNĚJŠÍ stejně velké nebo menší než VNITŘÍ, nedává smysl "  
                        " Prosím, změňte hodnoty posvníků a stiskněte tlačítko PŘIPRAV "
      stop]
    [restart]
end

;; tato procedura nastaví procento bílých buněk přiblžně podle hodnoty POCATECNI-HUSTOTA 
;; a zbytek nastaví černě. Pokud je POCATECNI-HUSTOTA na 50%, pak je polovina buněk
;; bílá a polovina černá
to restart
  reset-ticks
  ask patches
    [ ifelse random-float 100.0 < pocatecni-hustota
        [ set pcolor white ]
        [ set pcolor black ] ]
end

to go
  ask patches [ pick-new-color ]
  ask patches [ set pcolor new-color ]
  tick
end

to pick-new-color  ;; procedura políček
  let activator count inner-neighbors with [pcolor = white]
  let inhibitor count outer-neighbors with [pcolor = white]
  ;; nemusíme zde násobit "activator" žádným koeficientem, protože 
  ;; parametr POMER drží neporušenou proporci proměnných 
  let difference activator - pomer * inhibitor
  ifelse difference > 0
    [ set new-color white ]
    [ if difference < 0
        [ set new-color black ] ]
  ;; všimněte si, že jsme neošetřili případ, kdy difference = 0
  ;; to je tím, že v tomto případě nechceme, aby došlo ke změně barvy
end

;;; procedury pro definování chování sousedů v eliptickém okolí

to-report ellipse-in [x-radius y-radius]  ;; procedura políček
  report patches in-radius (max list x-radius y-radius)
           with [1.0 >= ((xdistance myself ^ 2) / (x-radius ^ 2)) +
                        ((ydistance myself ^ 2) / (y-radius ^ 2))]
end

to-report ellipse-ring [outx-radius outy-radius inx-radius iny-radius]  ;; procedura políček
  report patches in-radius (max list outx-radius outy-radius)
           with [1.0 >= ((xdistance myself ^ 2) / (outx-radius ^ 2)) +
                        ((ydistance myself ^ 2) / (outy-radius ^ 2))
             and 1.0 <  ((xdistance myself ^ 2) / (inx-radius ^ 2)) +
                        ((ydistance myself ^ 2) / (iny-radius ^ 2))
                ]
end

;; Následující dva reportery vrací hodoty x a y vzdáleností.
;; Lze si je představit jako vzdálenosti vrcholů trojůhelníku, 
;; určující "jak daleko do leva" a "jak daleko nahoru" jsou 
;; zbývající vrcholy od prvního vrcholu. Tato čísla jsou důležitá pro 
;; výpočet v eliptickém okolí buňky. 
  
;; Všimněte si, že je důležité použít primitivum DISTANCEXY a nikoliv
;; pouze absolutní hodnotu rozdílu v souřadnicích. Je to tak, protože
;; DISTANCEXY zachází s volnými (průchozími) okraji okna správně, pokud
;; je tato průchodnost zapnuta (což ve standardním nastavení tohoto modelu je).

to-report xdistance [other-patch]  ;; procedura políček
  report distancexy [pxcor] of other-patch
                    pycor
end

to-report ydistance [other-patch]  ;; procedura políček
  report distancexy pxcor
                    [pycor] of other-patch
end


; *** NetLogo 4.0.3 Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
;
; Copyright 2003 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2003).  NetLogo Fur model.
; http://ccl.northwestern.edu/netlogo/models/Fur.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2003 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/Fur
; for terms of use.
;
; *** End of NetLogo 4.0.3 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
309
10
624
346
30
30
5.0
1
10
1
1
1
0
1
1
1
-30
30
-30
30
1
1
1
ticks

CC-WINDOW
5
360
633
455
Command Center
0

BUTTON
205
60
294
93
Připrav
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
218
254
289
287
Start
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
7
221
179
254
pocatecni-hustota
pocatecni-hustota
0
100
50
1
1
%
HORIZONTAL

SLIDER
7
257
180
290
pomer
pomer
0
2
0.35
0.01
1
NIL
HORIZONTAL

BUTTON
217
216
290
249
1x Krok
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
216
179
289
212
Restart
restart
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
8
37
180
70
vnitrni-radius-x
vnitrni-radius-x
0
10
3
1
1
cells
HORIZONTAL

SLIDER
8
72
180
105
vnitrni-radius-y
vnitrni-radius-y
0
10
3
1
1
cells
HORIZONTAL

SLIDER
7
106
180
139
vnejsi-radius-x
vnejsi-radius-x
0
10
6
1
1
cells
HORIZONTAL

SLIDER
7
141
179
174
vnejsi-radius-y
vnejsi-radius-y
0
10
6
1
1
cells
HORIZONTAL

@#$#@#$#@
CO TO JE?
---------

Může existovat jeden jediný mechanismus, který by dokázal vytvářet takové zvířecí zbarvení, jako jsou zebří pruhy, skvrny leoparda nebo vzory na těle žirafy? Tento model nabízí možné vysvětlení, jak se mohou vzory zvířecí kůže samoorganizovat. Pokud je tento model správný, pak formování zvířecích vzorů způsobují stejná pravidla, která se pouze u jednotlivých zvířat liší některými hodnotami parametrů (se kterými tato pravidla pracují).

Zkoumáním formování vzorů v podobě pravidel či zákonitostí nám může také pomoci pochopit, jak může docházet k vytváření rozdílných vzorů mezi jednotlivými zvířaty a jejich potomstvem. Potomci mají zpravidla sice podobný vzor, avšak nikoliv zcela identický. To je způsobeno tím, že dědí od svých rodičů spíše soubor pravidel a hodnot namísto neměnného obrazce. Proces, při kterém tato pravidla a hodnoty vytváří vzory, je ovlivněn náhodnými faktory, čímž dochází k jedinečným vzorům na každém jedinci. Tak dlouho, jak bude potomstvo dědit tato pravidla a hodnoty, tak se bude dlouho jejich zbarvení samoorganizovat do stejných vzorů, jako měli jejich rodiče. 

JAK TO FUNGUJE?
---------------

Zvířecí kůže je v tomto modelu vytvářena skupinami malých čtverců představujících melanocyty (pigmentové buňky), které se mohou nacházet ve dvou odlišných stavech: zbarvená (dále jen „Z“) a bezbarvá (dále jen „B“). Stav buňky se může měnit mezi Z a B. Zbarvené buňky (Z) vylučují dva typy „morfogenů“: aktivátory (A) a inhibitory (I). Aktivátory způsobují zbarvení centrální buňky, inhibitory zase naopak způsobují, že centrální buňka bude bezbarvá. Tyto vzájemně si konkurující morfogeny jsou vylučovány všemi směry, čímž kolem sebe vytváří centrální buňka pomyslnou skvrnu, která se rozšiřuje k ostatním buňkám.

Každá z buněk (ať už zbarvená nebo bezbarvá) je sama centrem svého vlastního okolí. Nyní předpokládejme, že toto okolí má tvar kruhu. Řekněme, že toto okolí má rádius (poloměr) 6 buněk. To znamená, že buňka v centru je ovlivněna všemi ostatními buňkami, které leží v dosahu 6 buněk v jakémkoliv směru. Pokud je tedy v tomto okruhu Z buňka vypouštějící morfogeny, pak se morfogeny rozšíří až k této centrální buňce (avšak Z buňka ve vzdálenosti 7 buněk tuto centrální buňku přímo neovlivní). Zároveň má ovšem každá z buněk vnitřní kruhové okolí, jehož rádius je řekněme 3 buňky.

Buňky typu Z nacházející se ve vnitřním kruhu působí na centrální buňku morfogenem A (aktivátorem). Mezi vnitřním kruhem a okrajem vnějšího leží prstenec buněk, které jsou vzdálené více než 3 ale méně než 7 od centrální buňky. Každá Z buňka v tomto vnějším prstenci působí na centrální buňku naopak morfogeny I (inhibitory). Díky tomu je v každém okamžiku každá buňka ovlivněna aktivátory a inhibitory ze svého okolí a otázka zní, zda nakonec převáží aktivátory a buňka se zbarví, nebo naopak inhibitory a buňka ztratí barvu (nebo pouze zůstane v původním stavu). Logika spočívá v tom, že pokud je síla aktivátorů silnější než síla inhibitorů, pak se buňka zbarví a naopak (pokud jsou obě síly v rovnováze, žádná změna nenastane). Zmíněná myšlenka „síly“ spočívá v tom, že nestačí znát prostý počet morfogenů obou druhů působících na buňku, nýbrž je třeba působení každé buňky násobit její „silou“ (nebo je možné tuto sílu chápat jako koncentraci morfogenů ve vnitřním a vnějším okolí). Další myšlenka je, že pokud budeme násobit oba typy morfogenů jejich silou, můžeme vyjádřit sílu aktivátorů jako 1 a sílu inhibitorů jako „1 * w“ nebo pouze „w“. W je tedy poměr mezi silou inhibitorů a aktivátorů. Pokud je w větší než jedna, znamená to, že síla inhibitorů je větší než síla aktivátorů (když je například w = 2, pak jsou inhibitory dvakrát silnější než aktivátory; a pro w = 0,5 mají inhibitory poloviční sílu než aktivátory). Pokud je tedy w = 0,5 a máme stejný počet inhibitorů jako aktivátorů působících na centrální buňku, pak logicky předpokládáme, že centrální buňka bude více aktivována než inhibována, a proto se v modelu v tomto časovém kroku zbarví. (Důležité je si uvědomit, že ve chvíli, kdy některá Z buňka aktivuje sousední buňky, tato Z buňka zároveň inhibuje o něco vzdálenější buňky.)

Výše uvedená pravidla lze shrnout následujícím způsobem: Spočítají se všechny Z buňky ve vnějším prstenci a toto číslo se označí jako Z*I (například 2 inhibitory). Dále se spočítají všechny Z buňky ve vnitřním kruhu a označí se jako Z*A (například 5 aktivátorů). Poté vypočteme Z*A - w*Z*I a. Pokud je výsledek > 0, nastaví se centrální buňka do stavu Z; pokud je výsledek > 0, nastaví se centrální buňka do stavu B; pokud je výsledek = 0, zůstane centrální buňka beze změny.

Podstatné je, že tento výpočet probíhá pro všechny buňky ve stejnou chvíli. Po dokončení prvního kroku, ve kterém se všechny buňky nastaví do příslušných stavů, se celý proces opakuje znovu. Opět jsou přepočítány stavy jednotlivých buněk podle stejných pravidel. Pravidla se sice nemění, avšak některé z bývalých Z buněk jsou nyní ve stavu B a naopak, což může mít za následek odlišný výsledek - rozdílný výsledek „souboje“ mezi morfogeny A a I.

V modelu tedy vidíte krok za krokem jednotlivé buňky měnit barvu z bílé (reprezentující Z buňky) na černou (reprezentující B buňky) a celkový dojem se projevuje změnami celého uspořádání bílé a černé barvy. Avšak tato uspořádání nejsou náhodná. Často uvidíte, jak se tato uspořádání formují. Pochopení chování každé buňky, vysvětlené výše, nám může pomoci porozumět, jak se vytváří celkové vzory.

Všechna uvedená vysvětlení se týkala kruhového okolí buňky. V tomto modelu může být ovšem okolí buňky nejen kruhové ale také eliptické. Pomocí eliptického okolí lze vytvořit mimo skvrn také pruhové vzory. 

JAK MODEL OVLÁDAT
-----------------

Pokud chcete, aby váš první experiment s modelem zhruba odpovídal výše uvedenému popisu, nastavte posuvník POCATECNI-HUSTOTA na hodnotu 50 % (tím dáte každé z buněk stejnou šanci na to, aby se zbarvila černě nebo bíle, a tudíž bude celé okno přibližně z 50 % bílé), posuvníky VNITRNI-RADIUS-X a VNITRNI-RADIUS-Y na 3 a posuvníky VNEJSI-RADIUS-X a VNEJSI-RADIUS-Y na 6 a POMER na hodnotu 0,35 (to znamená, že morfogeny I jsou z 35 % tak silné jako morfogeny A). Nyní stiskněte tlačítko PŘIPRAV. (V dalších experimentech si zkuste změnit tato nastavení na různé další kombinace.) Může chvilku trvat, než se model připraví. Pokud poté stiskněte tlačítko 1x KROK, posunete model o jednu časovou jednotku. Stisknutím tlačítka START spustíte model v nepřetržitém běhu časových kroků.

Políčkům chvíli trvá, než ovlivní své sousedy. Z toho důvodu používejte tlačítko PŘIPRAV, pokud změníte hodnoty posuvníků určující rádius. Pokud chcete pouze změnit hodnoty posuvníků POCATECNI-HUSTOTA a POMER nebo pokud chcete spustit model s identickým nastavením, stiskněte tlačítko RESTART namísto tlačítka PŘIPRAV. Samotné stisknutí tlačítka RESET nepřepočítá okolí pro jednotlivá políčka. 

VŠIMNĚTE SI
-----------

Za běhu modelu mohou vznikat vzory, které se mohou stabilizovat (přestože se občas dostane do nekonečné oscilace mezi dvěma stavy, což ovšem můžeme nazvat dynamickou stabilitou). Přestože to vypadá, že se běh modelu zastavil, model stále běží s vykonáváním všech příkazů a výpočtů - žádné z nich se však viditelně neprojeví. To proto, že pro každou buňku jsou aktivátory a inhibitory v rovnováze a tudíž se nemění. 

VYZKOUŠEJTE SI
--------------

Spusťte model s různými hodnotami posuvníku POCATECNI-HUSTOTA. Jak (pokud vůbec) ovlivní hodnota tohoto nastavení vytváření vzorů? Vzniknou stejné vzory jako minule? Nebo vzniknou odlišné? Trvá tento proces déle?

Všimněte si, jak je samoorganizace buněk citlivá na malé změny parametrů. Pokud ponecháte všechny ostatní faktory nezměněné a budete měnit pouze hodnotu posuvníku POMER, uvidíte, že u nízkých hodnot dostanete vždy zcela bílé okno a u vysokých hodnot zase naopak zcela černou plochu (proč?). Pro střední hodnoty dochází k fluktuaci vzniklých vzorů. To je dáno prvotním zbarvením, které do modelu přináší náhodný prvek (prohlédněte si proceduru RESTART v kódu).

Zkuste změnit hodnoty posuvníků tak, abyste měli odlišné hodnoty X a Y u parametrů, které určují rádius buněk. 

ROZŠÍŘENÍ MODELU
----------------

Pokud naleznete takovou kombinaci hodnot parametrů, která konzistentně vytváří vzory kůže nějakého oblíbeného zvířete, můžete pro ni vytvořit vlastní tlačítko, například „Zebra“, které nastaví posuvníky právě na tyto vybrané hodnoty. Tímto způsobem (pokud jich vytvoříte více) si můžete pomocí přepínání vzorů projít v modelu svoje vlastní safari. Jedna z kombinací, kterou si můžete nastavit na samostatné tlačítko, je tato: VNITRNI-RADIUS-X 3 VNITRNI-RADIUS-Y 3 VNEJSI-RADIUS-X 6 VNEJSI-RADIUS-Y 6 POCATECNI-HUSTOTA 50% POMER 0,35.

Toto tlačítko můžete nazvat třeba „Ryba“.

A co přidání dalších barev? Co by zde bylo logické? Pokud byste přidali například červenou, měli byste se rozhodnout, za jakých specifických podmínek by se měla objevovat. Stejně tak byste měli rozhodnout, jak tato nová barva bude ovlivňovat ostatní barvy. 

SOUVISEJÍCÍ MODELY
------------------

Model Voting (volby) v sekci Social Science (společenské vědy) je založen na jednodušších pravidlech. Vytváří ovšem vzory, které jsou v jistých ohledech tomuto modelu podobné.


PODĚKOVÁNÍ A ODKAZY
----------------------
Mechanismus "rozptylem řízené nestability" byl poprvé navržen Alanem Turingem v roce 1952. B.N. Nagorcka prvně navrhl jeho využití na oblast růstu vlasů a srsti. Jednotlivé varianty prezentované v tomto modelu byly navrženy Davidem Youngem.

Při vytváření modelu jsme použili informace dostupné na této stránce:
http://classes.yale.edu/fractals/Panorama/Biology/Leopard/Leopard.html

Poděkování za práci na tomto modelu patří také Seth Tisue a Dor Abrahamson.

Při citování tohoto modelu ve vědeckých publikacích použijte prosím následující odkaz:  Wilensky, U. (2003).  NetLogo Fur model.  http://ccl.northwestern.edu/netlogo/models/Fur.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

V jiných publikacích uveďte prosím tyto informace: Copyright 2003 Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/Fur for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.3
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@